Toying with lights.

MRC; HACK MAC is a test program for the Panda Display.

GAMES; BREATH 1 is the "breathing" KI lights code, ported to ITS.

src/games/breath.1

@@ -0,0 +1,54 @@
+        TITLE BREATHING LIGHTS
+
+;Date: Fri, 6 May 94 17:19:56 PDT
+;From: Pat Tressel <tressel@decwet.enet.dec.com>
+;Subject: nostalgia
+;
+;I was cleaning out stuff I still had at Locke this past Saturday, when I
+;came across something I thought I'd lost long ago:
+;
+;0/  1,,0
+;1/  400000
+;2/  0
+;3/  0
+;
+;6/  movei 4,40000
+;7/  xor   3,1
+;10/ xor   3,0
+;11/ movem 3,2
+;12/ imuli 3,1
+;13/ dmove 2,2
+;14/ sojg  4,12
+;15/ rot   0,1
+;16/ rot   1,-1
+;17/ jrst  6
+;
+;(start at 6)
+;
+;This is (one version of) the "breathing" KI lights code.  (The other
+;version doesn't have the movem or dmove.)
+
+SLEEP==1
+PI==4
+
+START:	SETO 1,
+	.IOTLSR 1,
+
+	MOVE 0,[1,,0]
+	MOVEI 1,400000
+	MOVEI 2,0
+	MOVEI 3,0
+
+LOOP:	XOR 3,1
+	XOR 3,0
+	MOVEM 3,2
+	IMULI 3,1
+	DMOVE 2,2
+	DATAO PI,3
+	MOVEI 4,SLEEP
+	.SLEEP 4,
+	ROT 0,1
+	ROT 1,-1
+	JRST LOOP
+
+	END START

src/mrc/hack.mac

@@ -0,0 +1,44 @@
+	TITLE HACK
+	SEARCH MONSYM
+
+HACK:	SKIPA 4,[^D4]
+HACK0:	 SOJL 4,TRAILL
+	SETZB 1,3
+HACK1:	TLNE 1,777777
+	 JRST HACK0
+	MOVE 2,1
+	CIRC 2,-^D18
+	SKIPN 4
+	 SKIPA 1,3
+	  IOR 1,3
+	LITES%
+	 HALT
+	HRRZ 2,1
+	MOVEI 1,30
+	DISMS%
+	MOVE 1,2
+	AOJA 1,HACK1
+
+TRAILL: SETZ 1,
+TRALL0: LITES%
+	 HALT
+	MOVE 2,1
+	MOVEI 1,30
+	DISMS%
+	JUMPL 2,TRAILR
+	LSHC 1,^D37
+	AOJA 1,TRALL0
+
+TRAILR: MOVSI 1,400000
+TRALR0: LITES%
+	 HALT
+	MOVE 2,1
+	MOVEI 1,30
+	DISMS%
+	MOVE 1,2
+	TRNE 1,1
+	 JRST HACK
+	ASH 1,-1
+	JRST TRALR0
+
+	END HACK