mirror of
https://github.com/PDP-10/stacken.git
synced 2026-03-05 10:43:43 +00:00
66 lines
1.5 KiB
Plaintext
66 lines
1.5 KiB
Plaintext
TITLE FRCINI PROGRAM TO FORCE INITIA TO RUN ON ALL NON NETWORK LINES
|
||
|
||
SEARCH UUOSYM
|
||
TWOSEG
|
||
|
||
|
||
FRCWHO==0 ;WHO LAST EDITED (0 ORIGINAL AUTHOR)
|
||
FRCMAJ==1 ;MAJOR VERSION NUMBER
|
||
FRCMIN==0 ;MINOR VERSION NUMBER
|
||
FRCEDT==0 ;EDIT LEVEL
|
||
|
||
LOC 137
|
||
BYTE (3)FRCWHO (9)FRCMAJ (6)FRCMIN (18)FRCEDT
|
||
RELOC 0
|
||
|
||
A==1
|
||
B==2
|
||
C==3
|
||
SP==16
|
||
|
||
HSTNOD: BLOCK 1 ;NODE NUMBER OF HOST
|
||
|
||
FRCARG: SIXBIT /INITIA/ ;ARG BLOCK FOR FRCUUO
|
||
FRCUDX: EXP 0
|
||
FRCLEN==.-FRCARG
|
||
|
||
CTYUDX: BLOCK 1 ;UDX OF CTY
|
||
|
||
RELOC 400000
|
||
|
||
START: RESET
|
||
MOVE A,[SIXBIT /CTY/]
|
||
IONDX. A, ;GET UDX OF CTY
|
||
JSP SP,UUOERR ; FAILED
|
||
MOVEM A,CTYUDX ;SAVE FOR LATER
|
||
GTNTN. A, ;GET OUR HOST NODE NUMBER
|
||
JSP SP,UUOERR ; FAILED
|
||
HLRZM A,HSTNOD ;SAVE FOR LATER
|
||
MOVEI B,.UXTRM!4 ;START WITH TTY4
|
||
LCLLUP: CAML B,CTYUDX ;MAKE SURE WE DON'T GO BEYOND CTY
|
||
JRST LCLDUN ; LET THE OPERATOR TYPE .I FOR THE CTY
|
||
MOVE C,B ;COPY THE TERMINAL
|
||
GTNTN. C, ;GET ITS HOST NODE NUMBER
|
||
JRST LCLDUN ; FAILED, PROBABLY NOT CONNECTED
|
||
HLRZS C ;GET LEFT HALF
|
||
CAME C,HSTNOD ;IS IT THE SAME?
|
||
JRST LCLDUN ; NO, WE ARE ALL DONE
|
||
MOVEM B,FRCUDX ;SAVE THE TERMINAL UDX FOR FRCUUO
|
||
MOVE C,[XWD FRCLEN,FRCARG]
|
||
FRCUUO C, ;FORCE INITIA TO RUN
|
||
JSP SP,UUOERR ; FAILED
|
||
AOJA B,LCLLUP ;INCREMENT TO NEXT LINE
|
||
|
||
LCLDUN: OUTSTR [ASCIZ/
|
||
Forced INITIA to run on all non network lines.
|
||
Type .INITIA on the CTY to start the system.
|
||
/]
|
||
EXIT 0,
|
||
|
||
UUOERR: OUTSTR [ASCIZ/?UUO failed, PC of failing UUO can be found in AC 16
|
||
/]
|
||
SUBI SP,2 ;POINT TO FAILING UUO
|
||
HALT .
|
||
|
||
END START
|
||
|