Add missing files to src/cmd

src/cmd/ald.s

@@ -0,0 +1,256 @@
+"** 05-1-4.pdf page 13
+" ald
+
+   law 17
+   sys sysloc
+   dac crread
+   tad d1
+   dac crchar
+
+   law 4
+   sys sysloc
+   tad d14
+   dac systime
+
+loop:
+   jms holcard
+   lac o12
+   dac buf+4
+   lac d1
+   sys write; buf; 5
+   law 017
+   sys creat; buf
+   spa
+   jmp ferror
+   dac fo
+   dzm noc
+   law obuf
+   dac opt
+   dzm seq
+
+cloop:
+   jms bincard
+   lac buf
+   and o700
+   sad o500
+   skp
+   jmp notbin
+
+   -48
+   dac c1
+   lac buf+3
+   dac sum
+   dzm buf+3
+   law buf-1
+   dac 10
+   cla
+1:
+   add 10 i
+   isz c1
+   jmp 1b
+   sad sum
+   skp
+   jmp badcksum
+
+   lac buf+1
+   sad seq
+   skp
+   jmp badseq
+
+   -1
+   tad buf+2
+   cma
+   dac c1
+"** 05-1-4.pdf page 14
+   law buf+3
+   dac 10
+1:
+   lac 10 i
+   jms putword
+   isz c1
+   jmp 1b
+
+   isz seq
+   lac buf
+   sma
+   jmp cloop
+   lac noc
+   sna
+   jmp 1f
+   dac 0f
+   lac fo
+   sys write; obuf; 0;..
+1:
+   lac fo
+   sys close
+   sys exit
+
+holcard: 0
+   jms rawcard
+   lac 1f
+   dac buf
+   lac 1f+1
+   dac buf+1
+   lac 1f+2
+   dac buf+2
+   lac 1f+3
+   dac buf+3
+   jmp holcard i
+1: <xx>;040040;040040;040040
+
+bincard: 0
+   jms rawcard
+   -24
+   dac c
+   law tbuf-1
+   dac 8
+   law buf-1
+   dac 9
+1:
+   lac 8 i
+   alss 6
+   dac 1f
+   lac 8 i
+   dac 1f+1
+   lac 8 i
+   dac 1f+2
+   lac 1f+1
+   lrss 6
+   xor 1f
+   dac 9 i
+   lac 1f+1
+   alss 12
+   xor 1f+2
+   dac 9 i
+   isz c
+"** 05-1-4.pdf page 15
+   jmp 1b
+   jmp bincard i
+1: 0;0;0
+
+rawcard: 0
+   lac systime i
+   tad wtime
+   dac tmtime
+   -80
+   dac c
+   law tbuf-1
+   dac 8
+   crsb
+1:
+   dzm crread i
+2:
+   lac systime i
+   cma
+   tad tmtime
+   spa
+   jmp timeout
+   lac crread i
+   sna
+   jmp 2b
+   lac crchar i
+   dac 8 i
+   isz c
+   jmp 1b
+   law
+   dac 1f
+   isz 1f
+   jmp .-1
+   jmp rawcard i
+1: 0
+
+badcksum:
+   lac d1
+   sys write; m1; m1s
+   jms wait
+   jmp cloop
+
+badseq:
+   lac d1
+   sys write; m2; m2s
+   jms wait
+   jmp cloop
+
+notbin:
+   lac d1
+   sys write; m3; m3s
+   jms wait
+   jmp cloop
+
+timeout:
+   lac d1
+   sys write; m4; m4s
+   jms wait
+   jmp rawcard+1
+
+m1:
+  <ba>;<d 040; <ch>;<ec>;<ks>;<um>; 012
+"** 05-1-4.pdf page 16
+m1s = .-m1
+
+m2:
+   <ba>;<d 040; <se>;<qu>;<en>;<ce>; 012
+m2s = .-m2
+
+m3:
+   <no>;<t 040; <bi>;<na>;<ry>; 012
+m3s = .-m3
+
+m4:
+  <ti>;<me>;<ou>;<t 012
+m4s = .-m4
+
+wait: 0
+   las
+   dac 2f
+1:
+   las
+   sad 2f
+   jmp 1b
+   and d1
+   sna
+   jmp wait i
+   sys save
+2: 0
+
+putword: 0
+   dac opt i
+   isz opt
+   isz noc
+   lac noc
+   sad d2048
+   skp
+   jmp putword i
+   lac fo
+   sys write; obuf; 2048
+   dzm noc
+   law obuf
+   dac opt
+   jmp putword i
+   jmp putword i
+
+d1: 1
+d2048: 2048
+d14: 14
+o500: 0500
+o700: 0700
+o12: 012
+wtime: 300
+
+c: .=.+1
+c1: .=.+1
+buf: .=.+100
+tbuf: .=.+80
+fo: .=.+1
+seq: .=.+1
+sum: .=.+1
+obuf: .=.+2048
+noc: .=.+1
+opt: .=.+1
+"** 05-1-4.pdf page 17
+systime: .=.+1
+crread: .=.+1
+crchar: .=.+1
+tmtime: .=.+1
+
+crsb = 0706744

src/cmd/fop.s

@@ -0,0 +1,816 @@
+"** 09-1-35.pdf page 1
+jms = 0100000
+"
+q:0
+fmp = jms q
+
+  lac i q
+  garg
+  isz q
+  -1
+  tad aexp
+  tad hexp
+  dac aexp
+  lac ans
+  lmq
+  lac ams
+  sna cll
+  jmp 2f
+  lls 1
+  dac 3f
+  dac 4f
+  lacq
+  dac 1f
+  lac hls
+  lmq
+  lac hms
+  sna cll
+  jmp 2f
+  lls 1
+  dac hms
+  lacq
+  dac hls
+  lac hms
+  mul
+1:0
+  dac ans
+  lacq
+  dac ce10
+  lac hls
+  mul
+3:0
+  dac ams
+  lacq
+  tad ce10
+  glk
+  dzm ce10
+  tad ams
+  szl cll
+  isz ce10
+  tad ans
+  szl cll
+  isz ce10
+  dac ans
+  lac hms
+  mul
+4:0
+  dac ams
+  lacq
+  tad ans
+  szl cll
+  isz ce10
+  lmq
+  lac ce10
+"** 09-1-35.pdf page 2
+  tad ams
+  sma
+  jmp 5f
+  isz aexp
+  nop
+  lrs 1
+5:xor rsign
+  dac ams
+  lacq
+  dac ans
+  jmp i q
+2:dzm aexp
+  dzm ams
+  dzm ans
+  jmp i q
+"
+q:0
+fdv = jms q
+  lac i q
+  garg
+  isz q
+  lac hms
+  sna
+  sys save
+  ral
+  dac 2f
+  dac 3f
+  dac 4f
+  -1
+  tad hexp
+  cma
+  tad aexp
+  dac aexp
+  lac ans
+  lmq
+  lac ams
+  sna cll
+  jmp 8f
+  div
+2:0
+  szl
+  sys save
+  dac ce10
+  lacq
+  dac 5f
+  lac ce10
+  frdiv
+3:0
+  szl
+  sys save
+  lacq
+  dac ce10
+  lac hls
+  and o377777
+  frdiv
+4:0
+  szl
+  sys save
+  lacq
+  dac 2b
+  spa cla
+"** 09-1-35.pdf page 3
+  -1
+  tad 2b
+  cll
+  mul
+5:0
+  dzm 2b
+  spa
+  isz 2b
+  lls 1
+  dac 3b
+  lacq
+  spa
+  isz 3b
+  skp
+  isz 2b
+  lac ce10
+  lmq
+  lac 3b
+  sna
+  jmp 6f
+  cma
+  tad d1
+  stl
+  tad ce10
+  lmq
+  szl
+  isz 2b
+6:lac 2b
+  sma
+  tad d1
+  tad 5b
+  sma cll
+  jmp 7f
+  lrs 1
+  isz aexp
+  nop
+7:xor rsign
+  dac ams
+  lacq
+  dac ans
+  jmp i q
+8:dzm aexp
+  dzm ams
+  jmp i q
+
+q:0
+fad = jms q
+  lac i q
+  garg
+  isz q
+  lac hms
+  sna
+  jmp 4f
+  lac ams
+  sna
+  jmp 8f
+7:lac aexp
+  cma
+  tad hexp
+  sma
+  jmp 5f
+"** 09-1-35.pdf page 4
+  dac ce10
+  tad d34
+  spa cla
+  jmp 0f
+  lac ce10
+  cma
+  tad d1
+  xor o640500
+  dac 1f
+  lac hls
+  lmq
+  lac hms
+  cll
+1:lrs 0
+  dac hms
+  lacq
+  dac hls
+  lac rsign
+  sma
+  jmp 2f
+  lac hls
+  cll cma
+  tad d1
+  dac hls
+  lac hms
+  szl cma
+  tad d1
+  dac hms
+2:lac ams
+  rcr
+  dac ams
+  lac ans
+  rar
+  cll
+  tad hls
+  dac ans
+  glk
+  tad ams
+  tad hms
+  dac ams
+  sma
+  jmp 3f
+  lac ans
+  cma cll
+  tad d1
+  dac ans
+  lac ams
+  szl cma
+  tad d1
+  dac ams
+  lac o400000
+3:isz aexp
+  nop
+0:xor asign
+  and o400000
+  dac rsign
+  fno
+4:lac ams
+  xor rsign
+  dac ams
+  jmp i q
+"** 09-1-35.pdf page 5
+5:jms 6f
+  lac rsign
+  xor asign
+  dac asign
+  jmp 7b
+8:jms 6f
+  jmp 4b
+6:0
+  lac ans
+  lmq
+  lac hls
+  dac ans
+  lacq
+  dac hls
+  lac ams
+  lmq
+  lac hms
+  dac ams
+  lacq
+  dac hms
+  lac hexp
+  lmq
+  lac aexp
+  dac hexp
+  lacq
+  dac aexp
+  jmp i 6b
+"
+q:0
+fno = jms q
+  lac ans
+  sad ams
+  sza cll
+  jmp 1f
+  dzm aexp
+  dzm rsign
+  jmp i q
+ "
+1:lmq
+  lac ams
+  and o200000
+  sza
+  jmp i q
+  lac ams
+  cll
+  norm 36
+  dac ams
+  lacq
+  dac ans
+  lacs
+  tad o777743
+  cma
+  tad aexp
+  dac aexp
+  jmp i q
+"
+q:0
+fcp = jms q
+  lac i q
+  garg
+  isz q
+"** 09-1-35.pdf page 6
+  lac rsign
+  spa
+  jmp 1f
+  lac ams
+  dac 5f
+  xor asign
+  dac ams
+  sna
+  jmp 2f
+  lac hms
+  sna cma
+  jmp 3f
+  lac hexp
+  cma
+  tad d1
+  tad aexp
+  sza
+  jmp 4f
+2:lac hms
+  cma
+3:tad d1
+  tad 5f
+  sza
+  jmp 4f
+  lac hls
+  cma
+  tad d1
+  tad ans
+  sza
+4:xor asign
+  jmp i q
+1:lac ams
+  xor d1
+  jmp i q
+5:0
+
+q: 0
+garg = jms q
+   tad dm1
+   dac 8
+   lac i 8
+   dac hexp
+   lac i 8
+   lmq
+   and o377777
+   dac hms
+   lac i 8
+   dac hls
+   lacq
+   xor ams
+   and o400000
+   dac rsign
+   lac ams
+   and o400000
+   dac asign
+   lac ams
+   and o377777
+   dac ams
+   jmp i q
+
+q: 0
+"** 09-1-35.pdf page 7
+sfmp = jms q
+  lac i q
+  garg
+  isz q
+   -1
+  tad aexp
+  tad hexp
+  dac aexp
+   lac ams
+   sna rcl
+   jmp 2f
+   lmq
+   lac hms
+   sna rcl
+   jmp 2f
+   dac .+2
+   0641122; 0
+   sma
+   jmp 1f
+   rcr
+   xor rsign
+   dac ams
+   isz aexp
+   jmp i q
+   jmp i q
+1:
+   xor rsign
+   dac ams
+   jmp i q
+2:
+   dzm aexp
+  dzm ams
+  jmp i q
+
+q: 0
+sfdv = jms q
+   lac i q
+   garg
+   isz q
+   lac hexp
+   cma
+   tad aexp
+   tad d1
+   dac aexp
+   lac hms
+   sna ral cll
+   sys save
+   dac 1f
+   lac ams
+   frdiv; 1: 0
+   szl
+   sys save
+   lacq
+   spa
+   jmp 1f
+   xor rsign
+   dac ams
+   jmp i q
+1:
+   rcr
+   xor rsign
+"** 09-1-35.pdf page 8
+   dac ams
+   isz aexp
+   jmp i q
+   jmp i q
+q:0
+   sfad = jms q
+   -1
+   tad i q
+   isz q
+   dac 8
+   lac i 8
+   dac hexp
+   lac i 8
+   sma
+   jmp 1f
+   xor o377777
+   tad d1
+1:
+   lrss 1
+   dac hms
+   lac ams
+   sma
+   jmp 1f
+   xor o377777
+   tad d1
+1:
+   lrss 1
+   dac ams
+   lac hexp
+   cma
+   tad aexp
+   tad d1
+   sma
+   jmp 1f
+   cma
+   tad d1
+   dac tmp
+   lac ams
+   lmq
+   lac hms
+   dac ams
+   lacq
+   dac hms
+   lac hexp
+   dac aexp
+   lac tmp
+1:
+   tad dm18
+   sma
+   jmp 3f
+   tad o660522
+   dac 1f
+   lac hms
+1:
+   lrss 0
+   dzm rsign
+   tad ams
+   cll sma
+   jmp 1f
+   lmq
+   and o400000
+"** 09-1-35.pdf page 9
+   dac rsign
+   lacq
+   cma
+   tad d1
+   cll sma
+   jmp 1f
+   isz aexp
+   nop
+   rar
+1:
+   sna
+   jmp 1f
+   norm 18
+   xor rsign
+   dac ams
+   lacs
+   tad om60
+   cma
+   tad aexp
+   dac aexp
+   jmp i q
+1:
+   dzm aexp
+   dzm ams
+   jmp i q
+3:
+   lac ams
+   rcl
+   sma
+   jmp 1f
+   cma
+   tad d1
+   xor o400000
+1:
+   dac ams
+   jmp i q
+q: 0
+fld = jms q
+   -1
+   tad i q
+   dac 8
+   lac i 8
+   dac aexp
+   lac i 8
+   dac ams
+   lac i 8
+   dac ans
+   isz q
+   jmp i q
+
+q: 0
+fst = jms q
+   -1
+   tad i q
+   dac 8
+   lac aexp
+   dac i 8
+   lac ams
+   dac i 8
+   lac ans
+   dac i 8
+"** 09-1-35.pdf page 10
+   isz q
+   jmp i q
+
+q: 0
+fng = jms q
+   lac ams
+   sza
+   xor o400000
+   dac ams
+   jmp i q
+
+q: 0
+fix = jms q
+   lac aexp
+   spa sna
+   jmp 1f
+   tad dm18
+   sma
+   jmp 3f
+   cma
+   tad o660500
+   dac 2f
+   lac ams
+   sma
+   jmp 2f
+   xor o377777
+   tad d1
+2:
+   lrss 0
+   jmp i q
+1:
+   lac ams
+   lrss 18
+   jmp i q
+3:
+   lac ams
+   and o400001
+   sma
+   lac o377777
+   jmp i q
+
+q: 0
+flt = jms q
+   dac tmp
+   dzm ans
+   sma
+   jmp 1f
+   cma
+   tad d1
+   spa
+   cla
+1:
+   sza
+   jmp 1f
+   dzm aexp
+   dzm ams
+   jmp 2f
+1:
+   clq
+   norm 36
+   dac ams
+"** 09-1-35.pdf page 11
+   lacs
+   tad om56
+   cma
+   dac aexp
+2:
+   lac tmp
+   and o400000
+   xor ams
+   dac ams
+   jmp i q
+
+tmp: 0
+stmp: 0
+ce10: 0
+asign: 0
+aexp: 0
+ams: 0
+ans: 0
+hexp: 0
+hms: 0
+hls: 0
+
+q: 0
+sin = jms q
+   lac ams
+   and o400000
+   dac sign
+   lac ams
+   and o377777
+   dac ams
+   fst; ftmp1
+   fdv; fpi
+   fix
+   dac stmp
+   and d1
+   sna
+   jmp 1f
+   lac o400000
+   xor sign
+   dac sign
+1:
+   lac stmp
+   flt
+   fmp; fpi
+   fng
+   fad; ftmp1
+   fst; strm
+   fst; sres
+   fst; ftmp2
+   fld; fp1
+   fst; sfac
+   -6
+   dac scnt
+1:
+bsin:
+   fld; sfac
+   fad; fp1
+   fst; ftmp1
+   fad; fp1
+   fst; sfac
+   fld; strm
+"** 09-1-35.pdf page 12
+   fmp; ftmp2
+   fmp; ftmp2
+   fdv; sfac
+   fdv; ftmp1
+   fng
+   fst; strm
+   fad; sres
+   fst; sres
+   isz scnt
+   jmp 1b
+   lac ams
+   xor sign
+   dac ams
+   jmp i q
+
+q: 0
+sqrt = jms q
+   lac aexp
+   tad d1
+   llss 0
+   rar
+   dac aexp
+   lac ans
+   lmq
+   lac ams
+   spa
+   sys save
+   dac 1f
+   snl
+   jmp 5f
+   lls 1
+   dac ams
+   lacq
+   dac ans
+5:
+   lac 1f
+   sna
+   jmp q i
+   snl cll
+   xor o200000
+   xor o400000
+   dac 1f
+   lac ams
+   frdiv; 1:..
+   szl
+   clq
+   lacq
+   tad 1b
+   rar
+   cll
+   dac 2f
+   lac ams
+   frdiv; 2:..
+   szl
+   clq
+   lacq
+   tad 2b
+   rar
+   dac 3f
+   dac 4f
+   lac ans
+"** 09-1-35.pdf page 13
+   lmq
+   lac ams
+   cll
+   div; 3:..
+   szl
+   clq ecla
+   dac 1b
+   lacq
+   tad 3b
+   clq lrs 1
+   cll
+   lrs 1
+   dac ams
+   lacq
+   dac 2b
+   lac 1b
+   frdiv; 4:..
+   szl
+   sys save
+   lacq
+   lrs 2
+   tad 2b
+   dac ans
+   jmp q i
+
+sfac: 0;0;0
+ftmp1: 0;0;0
+ftmp2: 0;0;0
+strm: 0;0;0
+scnt: 0
+sres: 0;0;0
+rsign: 0
+sign: 0
+
+fp1: 1;0200000; 0
+
+o400000: 0400000
+o640500: 0640500
+o200000: 0200000
+d34: 34
+o777743: 0777743
+o2: 02
+o377777: 0377777
+dm18: -18
+o377777: 0377777
+om60: -060
+o660522: 0660522
+o660500: 0660500
+o400001: 0400001
+dm1: -1
+om56: -056
+fpi: 2;0311037; 0552421
+fpid2: 1; 0311037;0552421
+buf:
+cgarg = garg-jms
+cfmp = fmp-jms
+cfdv = fdv-jms
+cfad = fad-jms
+cfno = fno-jms
+cfcp = fcp-jms
+csfmp = sfmp-jms
+"** 09-1-35.pdf page 14
+csfdv = sfdv-jms
+csfad = sfad-jms
+cfld = fld-jms
+cfst = fst-jms
+cfng = fng-jms
+cfix = fix-jms
+cflt = flt-jms
+csin = sin-jms

src/cmd/psych.s

@@ -0,0 +1,304 @@
+" ** 11-56-91.pdf page 2
+" psych
+
+   lac d1
+   sys close
+   lac d13 "pushbuttons
+   sys sysloc
+   dac .pbp
+   tad d1
+   dac .pbp1
+restart:
+   fld; arg1
+   fst; g
+   fld; arg2
+   fst; fact
+   fld; fp01
+   fst; d
+   jms capture
+   -100
+   dac j
+   fld; fp0
+   fst; z
+   fst; oldx
+   fst; oldy
+   lac o400000
+   dac i 11
+   dac i 11
+   lac setx
+   dac i 10
+   lac sety
+   dac i 10
+
+loop:
+   sys time
+   fld; z
+   fad; fm110
+   fdv; radians
+   fst; b
+   fld; z
+   fad; g
+   fst; z
+   fld; g
+   fng
+   fmp; fact
+   fst; g
+   fld; fp1
+   fdv; fact
+   fst; fact
+   fld; b
+   fad; fpid2
+   sin
+   fmp; d
+   fmp; fp500
+   fst; xx
+   jms in
+   jmp done
+   fld; b
+   sin
+   fmp; d
+   fmp; fp500
+   fst; yy
+   jms in
+   jmp done
+" ** 11-56-91.pdf page 3
+   lac o400000
+   dac i 11
+   dac i 11
+   fld; oldx
+   fng
+   fad; xx
+   fix
+   spa
+   xor o775777
+   tad vecx
+   dac i 10
+   fld; oldy
+   fng
+   fad; yy
+   fix
+   spa
+   xor o775777
+   tad vecy
+   dac i 10
+   fld; xx
+   fst; oldx
+   fld; yy
+   fst; oldy
+   isz j
+   skp
+   jmp done
+   fld; g
+   fdv; fp90000
+   fad; d
+   fst; d
+   jmp loop
+
+done:
+   -1000
+   dac 9f
+   sys time
+   isz 9f
+   jmp .-2
+   skp
+9f:0
+   dzm char
+   lac auto
+   sza
+   jmp doauto
+1:
+   sys time " swap
+   lac i .pbp
+   sna
+   jmp 1b
+   spa ral
+   jmp 1f
+   spa ral
+   jmp 2f
+   spa ral
+   jmp 3f
+   spa ral
+   jmp 4f
+   spa ral
+   jmp 5f
+   spa ral
+   jmp 6f
+" ** 11-56-91.pdf page 4
+   spa ral
+   jmp 7f
+   jms release
+   sys exit
+7:
+   cla
+   sys read; tmp; 1
+   lac tmp
+   sad o141000
+   skp
+   jmp 0f
+   dac auto
+   dzm i .pbp1
+   jmp doauto
+0:
+   sad o12000
+   jmp restart
+   dzm g
+9:
+   cla
+   sys read; char; 1
+   lac char
+   sad o12000
+   jmp 9f
+   lrss 9
+   dac char
+   lac g
+   alss 3
+   tad char
+   tad om60
+   dac g
+   jmp 9b
+9:
+   lac tmp
+   sad o61000
+   jmp 9f
+   lac g
+   dac arg2
+   jmp restart
+9:
+   lac g
+   dac arg1
+   jmp restart
+5:
+   isz fp500
+   nop
+   jmp restart
+6:
+   -1
+   tad fp500
+   dac fp500
+   jmp restart
+4:
+   lac o400000
+   dac char
+3:
+   fld; arg1
+   fmp; fm056
+   lac char
+   spa
+   fng
+" ** 11-56-91.pdf page 5
+   fad; arg1
+   fst; arg1
+   jmp restart
+2:
+   lac o400000
+   dac char
+1:
+   fld; arg2
+   fmp; fm056
+   lac char
+   spa
+   fng
+   fad; arg2
+   fst; arg2
+   jmp restart
+
+doauto:
+   lac i .pbp1
+   sma
+   jmp 1f
+   dzm auto
+   jmp done
+1:
+   sys time
+   omq
+   tad 0
+   tad stick
+   cll
+   mul
+   78625
+   lls 9
+   dac stick
+   dzm aexp
+   and o177777
+   xor o200000
+   dac ams
+   fad; fmhalf
+   fmp; fp128
+   lac stick
+   and d1
+   sna
+   jmp 1f
+   fst; arg1
+   jmp restart
+1:
+   fst; arg2
+   jmp restart
+
+in: 0
+   fix
+   tad d500
+   spa
+   jmp i in
+   tad dm1000
+   spa
+   isz in
+   jmp i in
+
+capture: 0
+   law buf-1
+   dac 10
+" ** 11-56-91.pdf page 6
+   dac 11
+   lac o400000
+   dac i 11
+   law buf
+   sys capt
+   jmp i capture
+
+release: 0
+   sys rele
+   jmp i release
+
+char: 0
+stick: 0
+xx: 0; 0; 0
+oldx: 0; 0; 0
+yy: 0; 0; 0
+oldy: 0;0 0; 0
+j: 0
+auto: 0
+
+setx: 0142000 +512
+sety: 0146000 +512
+vecx: 0100000
+vecy: 0124000
+o775777: 0775777
+o177777: 0177777
+o12000: 012000
+o61000: 061000
+om60: -060
+d13: 13
+d500: 500
+o141000: 0141000
+fp128:8; 0240000; 0
+fmhalf: 0; 0600000; 0
+dm1000: -1000
+
+fact: 0;0;0
+g: 0;0;0
+z: 0;0;0
+b: 0;0;0
+d: 0;0;0
+
+radians: 6;0345136;0
+fm110: 7;0734000;0
+arg1: 7;0234167;0
+arg2: 1;0275531;0
+fp0: 0;0;0
+fp01: -6;0243656;0
+fm056: -4;0745301;0
+fp500: 11;0372000;0
+fp90000: 021;0257620;0
+   .pbp: .=.+1
+   .pbp1: 0
+buf:

src/cmd/st1.s

@@ -0,0 +1,253 @@
+"** 12-92-119.pdf page 1
+" space travel 1
+
+t = 0
+
+start:
+	law 13
+	sys sysloc
+	dac .pbson
+	lac pww
+	dac 1f
+	dac 2f
+	lac pw
+	dac 3f
+	-32
+	dac cplan
+4:
+	fld; 1:0
+	fmp; 2:0
+	-1
+	tad aexp
+	dac aexp
+	fng
+	fad; fpone
+	fst; 3:0
+	lac 1b
+	tad d3
+	dac 1b
+	dac 2b
+	lac 3b
+	tad d3
+	dac 3b
+	isz cplan
+	jmp 4b
+	law dspl-1
+	dac clistp
+	dac lanflg
+	dzm crflg
+	dzm goflg
+	dzm .pbsint
+	dzm forflg
+	dzm bacflg
+	dzm dspflg
+	dzm locflg
+	dzm locpar
+	lac d1
+	dac par
+	jms dispname
+	fld; prsq+4
+	sqrt
+	fst; rpar
+	fst; y
+	fst; oy
+	fld; fpone
+	fst; sphi
+	fst; stheta
+	jms dspsca
+	fld; fpzero
+	fst; x
+	fst; ox
+	fst; cphi
+	fst; ctheta
+	law displist
+"** 12-92-119.pdf page 2
+	sys capt
+	jmp loop
+
+loop:
+	law dspl-1
+	dac clistp
+	jms contrl
+	lac par
+	jms absxy
+	jms shipxy
+	lac goflg
+	spa
+	jmp loop3
+	fld; fpzero
+	fst; ax
+	fst; ay
+	fst; maxa
+	lac nplan
+	skp
+loop1:
+	lac cplan
+	tad dm1
+	spa
+	jmp loop2
+	dac cplan
+	tad fppar
+	dac fcplan
+	lac i fcplan
+	dac fcplan
+	jms updacc
+	jms displa
+	lac cplan
+	sza
+	jms updpln
+	lac cplan
+	and o7
+	sad o7
+	jms contrl
+	jmp loop1
+
+loop2:
+	lac lanflg
+	sma
+	jms updshp
+loop3:
+	fld; horizv
+	lac scale
+	cma
+	tad vscale
+	tad aexp
+	dac aexp
+	jms inscr
+		jmp loop4
+	tad o141577
+	dac i clistp
+	lac o164372
+	dac clistp i
+	cla
+	jms dsplanet
+loop4:
+	sys time "put delay here.....
+"** 12-92-119.pdf page 3
+	dzm dispcl
+	lac crflg
+	sma
+	jmp 1f
+	lac o20714 "cl
+	dac dispcl
+	jmp 2f
+1:
+	lac lanflg
+	sma
+	jmp 2f
+	lac o114 "l
+	dac dispcl
+2:
+	lac dhalt
+	dac i clistp
+	jmp loop " check 2-display question
+
+contrl: 0
+	lac i .pbson
+	xor .pbsint
+	and .pbson i
+	sna
+	jmp noneon
+	lmq
+	spa ral
+	sys exit
+	sma
+	jmp 1f
+	dzm goflg
+	dzm crflg
+1:
+	lacq
+	als 6
+	sma ral
+	jmp 1f
+	spa
+	jmp noneon
+	isz scale
+	nop
+	jms dspsca "uprange
+	jmp noneon
+1:
+	sma
+	jmp noneon
+	-1
+	tad scale
+	dac scale
+	jms dspsca "downrange
+noneon:
+	dzm forflg
+	dzm bacflg
+	lac i .pbson
+	dac .pbsint
+	als 2
+	sma
+	jmp 1f
+	lac dhalt
+	dac forflg
+	lac goflg
+	sma
+"** 12-92-119.pdf page 4
+	dzm lanflg
+1:
+	lac i .pbson
+	als 3
+	sma
+	jmp 1f
+	lac dhalt
+	dac bacflg
+	lac goflg
+	sma
+	dzm lanflg
+1:
+	lac i .pbson
+	als 4
+	sma
+	jmp 1f
+	ral
+	spa
+	jmp i contrl
+	dzm 9f+t
+	jmp 2f
+1:
+	ral
+	sma
+	jmp i contrl
+	lac dhalt
+	dac 9f+t
+2:
+	fld; cphi
+	fmp; sdphi
+	lac 9f+t
+	sma
+	fng
+	fst; ftmp1
+	fld; sphi
+	fmp; cdphi
+	fad; ftmp1
+	fst; ftmp2
+	fld; sphi
+	fmp; sdphi
+	lac 9f+t
+	spa
+	fng
+	fst; ftmp1
+	fld; cphi
+	fmp; cdphi
+	fad; ftmp1
+	fst; cphi
+	fld; ftmp2
+	fst; sphi
+	jmp i contrl
+
+t = t+1
+
+shipxy: 0
+	fld; absx
+	fad; x
+	fng
+	fst; shipx
+	fld; absy
+	fad; y
+"** 12-92-119.pdf page 5
+	fng
+	fst; shipy
+	jmp i shipxy

src/cmd/st2.s

@@ -0,0 +1,222 @@
+"** 12-92-119.pdf page 6
+	" space travel 2
+
+absv: 0
+	dzm absx
+	dzm absx+1
+	dzm absx+2
+	dzm absy
+	dzm absy+1
+	dzm absy+2
+1:
+	dac absi
+	sna
+	jmp i absv
+	tad fppar
+	dac 9f+t
+	jms invert
+	fld; ftmp1
+	fng
+	fad; absx
+	fst; absx
+	fld; ftmp2
+	fng
+	fad; absy
+	fst; absy
+	jms invert
+	fld; ftmp1
+	fad; absx
+	fst; absx
+	fld; ftmp2
+	fad; absy
+	fst; absy
+	lac absi
+	tad ppar
+	dac 9f+t
+	lac i 9f+t
+	jmp 1b
+
+invert: 0
+	lac i 9f+t
+	dac fcplan
+	tad pww
+	dac 1f
+	dac 2f
+	lac fcplan
+	tad px
+	dac 3f
+	lac fcplan
+	tad py
+	dac 4f
+	fld; 1:..
+	fng
+	fst; 2:..
+	jms updpln
+	fld; 3:..
+	fst; ftmp1
+	fld; 4:..
+	fst; ftmp2
+	jmp i invert
+
+	t = t+1
+
+updpln: 0
+"** 12-92-119.pdf page 7
+	lac fcplan
+	lmq
+	tad px
+	dac 1f
+	dac 5f
+	lacq
+	tad py
+	dac 3f
+	dac 6f
+	dac 0f
+	lacq
+	tad pw
+	dac 2f
+	dac 7f
+	lacq
+	tad pww
+	dac 4f
+	dac 8f
+
+	fld; 1:..
+	fst; ftmp1
+	fmp; 2:..
+	fst; ftmp2
+	fld; 3:..
+	fmp; 4:..
+	fng
+	fad; ftmp2
+	fst; 5:..
+	fld; 6:..
+	fmp; 7:..
+	fst; ftmp2
+	fld; ftmp1
+	fmp; 8:..
+	fad; ftmp2
+	fst; 0:..
+	jmp updpln i
+
+updacc: 0
+	lac cplan
+	sad par
+	jmp upda2
+	jms absxy
+	fld; absx
+	fad; shipx
+	jmp 1f
+upda2:
+	fld; x
+	fng
+1:
+	fst; absx
+	fmp; absx
+	fst; ftmp1
+	lac cplan
+	sad par
+	jmp 1f
+	fld; absy
+	fad; shipy
+	jmp 2f
+1:
+	fld; y
+	fng
+"** 12-92-119.pdf page 8
+2:
+	fst; absy
+	fmp; absy
+	fad; ftmp1
+	fst; dtmp1
+	sqrt
+	fst; dpar
+	lac cplan
+	sad par
+	skp
+	jmp upda5
+	fld; ox
+	fng
+	fad; x
+	fst; ftmp1
+	fmp; y
+	fst; horizv
+	fld; y
+	fng
+	fad; oy
+	fst; ftmp2
+	fmp; x
+	fad; horizv
+	fdv; dpar
+	fst; horizv
+	fld; dpar
+	fcp; rpar
+	sma
+	jmp upda5
+	lac lanflg
+	spa
+	jmp upda5
+	fld; ftmp1
+	fmp; ftmp1
+	fst; ftmp1
+	fld; ftmp2
+	fmp; ftmp2
+	fad; ftmp1
+	fcp; crash
+	spa
+	jmp 1f
+	lac dhalt
+	dac goflg
+	dac crflg
+1:
+	lac dhalt
+	dac lanflg
+	fld; rpar
+	fdv; dpar
+	fst; ftmp1
+	fmp; x
+	fst; x
+	fst; ox
+	fld;  ftmp1
+	fmp; y
+	fst; y
+	fst; oy
+	lac par
+	jms absxy
+	jms shipxy
+	jmp upda2
+"** 12-92-119.pdf page 9
+upda5:
+	fcp; fardst
+	spa
+	jmp 1f
+	lac cplan
+	sna
+	jmp 1f
+	lac dhalt
+	dac grvflg
+	jmp i updacc
+1:
+	dzm grvflg
+	lac fcplan
+	tad accl
+	dac 1f
+	fld; 1:..
+	fdv; dtmp1
+	fcp; maxa
+	spa
+	jmp 2f
+	fst; maxa
+	lac cplan
+	dac maxj
+2:
+	fdv; dpar
+	fst; ftmp1
+	fmp; absx
+	fad; ax
+	fst; ax
+	fld; ftmp1
+	fmp; absy
+	fad; ay
+	fst; ay
+	jmp i updacc

src/cmd/st3.s

@@ -0,0 +1,188 @@
+"** 12-92-119.pdf page 10
+	" space travel 3
+
+updshp: 0
+	lac forflg
+	spa
+	jmp .+4
+	lac bacflg
+	sma
+	jmp 3f
+	fld; ascale
+	lac  forflg
+	sma
+	jmp 1f
+	lac bacflg
+	sma
+	jmp 1f+1
+	fld; fpzero
+	jmp 2f
+1:
+	fng
+	lac scale
+	tad aexp
+	dac aexp
+	lac forflg
+	sma
+	jmp .+3
+2:
+	lac accflg
+	sma
+	jmp .+3
+	fad; maxa
+	fng
+	fst; ftmp1
+	fmp; ctheta
+	fad; ax
+	fst; ax
+	fld; ftmp1
+	fmp; stheta
+	fad; ay
+	fst; ay
+3:
+	fld; ox
+	fng
+	fad; ax
+	fst; ftmp1
+	fld; x
+	lac aexp
+	tad d1
+	dac aexp
+	fad; ftmp1
+	fst; ftmp1
+	fld; x
+	fst; ox
+	fld; ftmp1
+	fst; x
+	fld; oy
+	fng
+	fad; ay
+	fst; ftmp1
+	fld; y
+	lac aexp
+	tad d1
+"** 12-92-119.pdf page 11
+	dac aexp
+	fad; ftmp1
+	fst; ftmp1
+	fld; y
+	fst; oy
+	fld; ftmp1
+	fst; y
+	lac par
+	sad maxj
+	jmp i updshp
+	jms absxy
+	jms shipxy
+	lac par
+	jms absv
+	fld; ox
+	fng
+	fad; x
+	fad; absx
+	fst; ox
+	fld; oy
+	fng
+	fad; y
+	fad; absy
+	fst; oy
+	lac maxj
+	dac par
+	jms absv
+	fld; ox
+	fng
+	fad; absx
+	fst; ox
+	fld; oy
+	fng
+	fad; absy
+	fst; oy
+	lac par
+	jms absxy
+	fld; absx
+	fad; shipx
+	fng
+	fst; x
+	fad; ox
+	fst; ox
+	fld; absy
+	fad; shipy
+	fng
+	fst; y
+fadins:
+	fad; oy
+	fst; oy
+	lac par
+	tad fppar
+	dac 1f
+	lac i 1f
+	tad prsq
+	dac 1f
+	fld; 1:..
+	sqrt
+	fst; rpar
+	jms dspsca
+	lac par
+"** 12-92-119.pdf page 12
+	jms dispname
+	jmp i updshp
+
+inscr: 0
+	fng
+	fix
+	tad d383
+	spa
+	jmp i inscr
+	tad dm768
+	sma
+	jmp i inscr
+	isz inscr
+	jmp i inscr
+
+absxy: 0
+	sna
+	jmp 7f
+	lmq
+	lac fldins
+	dac 2f-1
+	dac 4f-1
+	lacq
+1:
+	dac absi
+	sna
+	jmp i absxy
+	tad fppar
+	dac 9f+t
+	lac i 9f+t
+5:
+	tad px
+	dac 2f
+fldins:
+	fld; absx
+	fad; 2:..
+	fst; absx
+	lac i 9f+t
+6:
+	tad py
+	dac 4f
+	fld; absy
+	fad; 4:..
+	fst; absy
+	lac fadins
+	dac 2b-1
+	dac 4b-1
+	lac absi
+	tad ppar
+	dac 9f+t
+	lac i 9f+t
+	jmp 1b
+7:
+	dzm absx
+	dzm absx+1
+	dzm absx+2
+	dzm absy
+	dzm absy+1
+	dzm absy+2
+	jmp i absxy
+"** 12-92-119.pdf page 13
+	t = t+1

src/cmd/st4.s

@@ -0,0 +1,255 @@
+"** 12-92-119.pdf page 14
+	" space travel 4
+
+displa: 0
+	lac locpar
+	sad cplan
+	skp
+	jmp 2f
+	lac locflg
+	sma
+	jmp 1f
+	fld; cphi
+	fmp; absy
+	fst; ftmp1
+	fld; sphi
+	fmp; absx
+	fad; ftmp1
+	fdv; dpar
+	fst; stheta
+	fld; sphi
+	fmp; absy
+	fng
+	fst; ftmp1
+	fld; cphi
+	fmp; absx
+	fad; ftmp1
+	fdv; dpar
+	fst; ctheta
+	jmp 2f
+1:
+	fld; sphi
+	fst; stheta
+	fld; cphi
+	fst; ctheta
+2:
+	fld; absx
+	sfmp; ctheta
+	fst; ftmp1
+	fld; absy
+	sfmp; stheta
+	fad; ftmp1
+	lac aexp
+	cma
+	tad scale
+	cma
+	dac aexp
+	fst; spy
+	dzm inflg
+	jms inscr
+		jmp 1f
+	tad o145777
+	dac clistp i
+	jms rotx
+	lac dhalt
+	dac inflg
+	jms inscr
+		jmp 1f
+	tad o161577
+	dac i clistp
+	lac cplan
+	jms dsplanet
+1:
+	jms drcirc
+"** 12-92-119.pdf page 15
+	jmp i displa
+
+rotx: 0
+	fld; absx
+	sfmp; stheta
+	fst; ftmp1
+	fld; absy
+	sfmp; ctheta
+	fng
+	fad; ftmp1
+	lac aexp
+	cma
+	tad scale
+	cma
+	dac aexp
+	fst; spx
+	jmp i rotx
+
+surf: 0
+	-1
+	tad setx
+	cma
+	dac tsetx
+	lac setx
+	tad o141577
+	dac i clistp
+	-1
+	tad sety
+	cma
+	dac tsety
+	lac sety
+	tad o165777
+	dac clistp i
+	lac narcs
+	dac nt
+	fld; wx
+	fst; twx
+	fld; wy
+	fst; twy
+	fld; v
+	fng
+	fst; v
+2:
+	fld; v
+	sfmp; twy
+	fng
+	fst; ftmp1
+	fld; vv
+	sfmp; twx
+	fad; ftmp1
+	fst; ftmp2
+	fld; v
+	sfmp; twx
+	fst; ftmp1
+	fld; vv
+	sfmp; twy
+	fad; ftmp1
+	fst; twy
+	fad; spy
+	jms inscr
+		jmp 1f
+"** 12-92-119.pdf page 16
+	tad tsety
+	dac dely
+	cma
+	tad d1
+	tad tsety
+	dac tsety
+	fld; ftmp2
+	fst; twx
+	fad; spx
+	jms inscr
+		jmp 1f
+	tad tsetx
+	dac delx
+	cma
+	tad d1
+	tad tsetx
+	dac tsetx
+	lac delx
+	sma
+	jmp .+3
+	cma
+	tad o41
+	alss 6
+	dac delx
+	lac dely
+	sma
+	jmp .+3
+	cma
+	tad o41
+	tad delx
+	tad o220000
+	dac i clistp
+	isz nt
+	jmp 2b
+	jmp i surf
+1:
+	isz surf
+	jmp i surf
+
+drcirc: 0
+	lac grvflg
+	spa
+	jmp i drcirc
+	lac fcplan
+	tad prsq
+	dac .+2
+	fld; ..
+	sqrt
+	lac aexp
+	cma
+	tad scale
+	cma
+	dac aexp
+	fst; dtmp1
+	fcp; thrs
+	spa
+	jmp i drcirc
+	fng
+	lac dpar
+	cma
+	tad scale
+"** 12-92-119.pdf page 17
+	cma
+	dac dpar
+	fad; dpar
+	sfdv; dpar
+	fst; dtmp2
+	sfmp; spy
+	fst; wy
+	jms inscr
+		jmp i drcirc
+	dac sety
+	lac inflg
+	sma
+	jms rotx
+	fld; dtmp2
+	sfmp; spx
+	fst; wx
+	jms inscr
+		jmp i drcirc
+	dac setx
+	fld; spy
+	fng
+	fad; wy
+	fst; wy
+	fld; spx
+	fng
+	fad; wx
+	fst; wx
+	fld; dtmp1
+	sfmp; pid10
+	fcp; f400
+	spa
+	jmp 1f
+	lac d400
+	dac narcs
+	jmp 2f
+1:
+	fix
+	tad dm20
+	spa
+	cla
+	tad d20
+	dac narcs
+	flt
+2:
+	fst; dtmp1
+	-1
+	tad narcs
+	cma
+	dac narcs
+	fld; f2pi
+	sfdv; dtmp1
+	fst; v
+	sfmp; v
+	-1
+	tad aexp
+	dac aexp
+	fng
+	fad; fpone
+	fst; vv
+	lac o40004
+	dac i clistp
+"** 12-92-119.pdf page 18
+	jms surf
+		jmp i drcirc
+	jms surf
+		jmp i drcirc
+	jmp i drcirc

src/cmd/st5.s

@@ -0,0 +1,75 @@
+"** 12-92-119.pdf page 19
+" space travel 5
+
+dsplanet: 0
+	tad points
+	dac 9f+t
+	lac i 9f+t
+	dac i clistp
+	lac o246256
+	dac i clistp
+	lac o253052
+	dac i clistp
+	lac o246036
+	dac i clistp
+	jmp dsplanet i
+
+dispname: 0
+	tad names
+	dac 9f+t
+	lac i 9f+t
+	tad dm1
+	dac 8
+	law namedsp-1
+	dac 9
+	-10
+	dac 9f+t
+1:
+	lac i 8
+	sna
+	jmp 2f
+	dac 9f+t+1
+	lrss 9
+	dac i 9
+	isz 9f+t
+	skp
+	jmp i dispname
+	lac 9f+t+1
+	and o177
+	sna
+	jmp 2f
+	dac i 9
+	isz 9f+t
+	jmp 1b
+	jmp i dispname
+2:
+	dzm i 9
+	isz 9f+t
+	jmp 2b
+	jmp i dispname
+
+t = t+2
+
+dspsca: 0
+	lac scale
+	sma
+	jmp 1f
+	lac o55 "-
+	dac dssca
+	-1
+	tad scale
+	cma
+	jmp 2f
+1:
+"** 12-92-119.pdf page 20
+	lac o53 "+
+	dac dssca
+	lac scale
+2:
+	cll; idiv; 10
+	tad o60
+	dac dssca+2
+	lacq
+	tad o60
+	dac dssca+1
+	jmp i dspsca

src/cmd/st6.s

@@ -0,0 +1,292 @@
+"** 12-92-119.pdf page 21
+"space travel 6 -- tables
+
+names: .+1
+sun
+earth
+ariel
+callisto
+moon
+deimos
+dione
+enceladus
+europa
+ganymede
+hyperion
+iapetus
+io
+jupiter
+mars
+mercury
+mimas
+miranda
+neptune
+nereid
+oberon
+phobos
+phoebe
+pluto
+rhea
+saturn
+tethys
+titan
+triton
+umbriel
+uranus
+venus
+
+sun: <su>;<n
+earth: <ea>;<rt>;<h
+ariel: <ar>;<ie>; <l
+callisto: <ca>;<ll>;<is>;<to>;0
+moon: <mo>;<on>;0
+deimos: <de>;<im>;<os>;0
+dione: <di>;<on>;<e
+enceladus: <en>;<ce>;<la>;<du>;<s
+europa: <eu>;<ro>;<pa>;0
+ganymede: <ga>;<ny>;<me>;<de>;0
+hyperion: <hy>;<pe>;<ri>;<on>;0
+iapetus: <ia>;<pe>;<tu>;<s
+io: <io>;0
+jupiter: <ju>;<pi>;<te>;<r
+mars: <ma>;<rs>;0
+mercury: <me>;<cu>;<ry>;0
+mimas: <mi>;<ma>;<s
+miranda: <mi>;<ra>;<nd>;<a
+neptune: <ne>;<pt>;<un>;<e
+nereid: <ne>;<re>;<id>;0
+oberon: <ob>;<er>;<on>;0
+phobos: <ph>;<ob>;<os>;0
+phoebe: <ph>;<oe>;<be>;0
+pluto: <pl>;<ut>;<o
+rhea: <rh>;<ea>;0
+saturn: <sa>;<tu>;<rn>;0
+"** 12-92-119.pdf page 22
+tethys: <te>;<th>;<ys>;0
+titan: <ti>;<ta>;<n
+triton: <tr>;<it>;<on>;0
+umbriel: <um>;<br>;<ie>;<l
+uranus: <ur>;<an>;<us>;0
+venus: <ve>;<nu>;<s
+
+points: .+1
+br3
+br2
+br0
+br2
+br1
+br0
+br1
+br0
+br1
+br2
+br0
+br1
+br1
+br3
+br2
+br1
+br0
+br0
+br3
+br0
+br1
+br0
+br0
+br1
+br1
+br3
+br1
+br2
+br1
+br0
+br3
+br2
+
+fppar:  .+1
+0;3;6;9;12;15;18;21
+24;27;30;33;36;39;42;45
+48;51;54;57;60;63;66;69
+72;75;78;81;84;87;90;93
+
+ppar: .+1
+0;0;036;015;01;016;031;031
+015;015;031;031;015;0;0;0
+031;036;0;022;036;016;031;0
+031;0;031;031;022;036;0;0
+
+prsq: .+1
+016;0272245;075341
+1;0200000;0
+-07;0244122;0506362
+-02;0251477;0620663
+-03;0230761;0127762
+-025;0320300;054474
+-06;0324134;0124211
+"** 12-92-119.pdf page 23
+-010;0335416;0541570
+-04;0371372;0
+-06;0247430;0
+-011;0311150;0
+-05;0302622;0
+-02;0256475;0
+07;0376733;0
+-01;0221530;0
+-02;0235142;0
+-010;0217266;0
+-011;0274361;0
+04;0365471;0
+-012;0227176;0
+-06;0342454;0
+-023;0326340;0
+-013;0326265;0
+-02;0323774;0
+-05;0255140;0
+07;0263573;0
+-06;0223174;0
+-02;0251477;0
+-02;0235142;0
+-05;0223060;0
+05;0206115;0
+0;0362406;0
+
+accl: .+1
+0;0204365;0
+-023;0320324;0
+-036;0227207;0
+-017;0340500;0
+-030;0210041;0
+-063;0341666;0
+-034;0235122;0
+-037;0247531;0
+-031;0310316;0
+-027;0334427;0
+-041;0315203;0
+-033;0303403;0
+-030;0245752;0
+-017;0201414;0
+-026;0263753;0
+-026;0205241;0
+-040;0256464;0
+-041;0272051;0
+-017;0340566;0
+-043;0275073;0
+-034;0255345;0
+-060;0341650;0
+-044;0341552;0
+-020;0307762;0
+-033;0243712;0
+-014;0233053;0
+-035;0265543;0
+-027;0340500;0
+-027;0210344;0
+-037;0210777;0
+-017;0275653;0
+-023;0252667;0
+
+px: .+1
+"** 12-92-119.pdf page 24
+0;000000;0
+015;0620356;0
+005;0360005;0
+010;0666214;0
+005;0704053;0
+002;0347600;0
+005;0310506;0
+006;0220622;0
+007;0310473;0
+004;0370065;0
+006;0304101;0
+011;0676631;0
+006;0653020;0
+020;0317202;0
+017;0644356;0
+013;0206414;0
+005;0245346;0
+004;0222264;0
+023;0261234;0
+001;0372225;0
+007;0646102;0
+001;0212446;0
+013;0773152;0
+024;0274557;0
+004;0227474;0
+020;0263122;0
+004;0333254;0
+010;0216672;0
+006;0231142;0
+006;0212701;0
+023;0650051;0
+016;0233751;0
+
+py: .+1
+000;0000000;0
+017;0664054;0
+002;0662035;0
+010;0350757;0
+006;0334771;0
+000;0267000;0
+006;0726770;0
+004;0225752;0
+006;0201346;0
+010;0247536;0
+010;0343277;0
+011;0314411;0
+006;0712237;0
+021;0334656;0
+017;0342324;0
+016;0615151;0
+005;0644257;0
+005;0622456;0
+024;0224063;0
+012;0331314;0
+006;0640034;0
+001;0200024;0
+011;0243161;0
+023;0772355;0
+007;0644432;0
+022;0726324;0
+006;0260740;0
+"** 12-92-119.pdf page 25
+010;0600213;0
+006;0237476;0
+005;0674734;0
+023;0616334;0
+016;0327155;0
+
+pw: .+1
+.=.+32+32+32
+
+pww: .+1
+0000;0000000;0000000
+-054;0663265;0376074
+-036;0743326;0460356
+-043;0647730;0444215
+-045;0767246;0341205
+-034;0745027;0221674
+-036;0702670;0530661
+-034;0702340;0273047
+-037;0747771;0100452
+-041;0743411;0732756
+-044;0716603;0200021
+-050;0755641;0517072
+-035;0751602;0332677
+-072;0631066;0300145
+-056;0712656;0015171
+-050;0701167;0507203
+-033;0715124;0202507
+-034;0665024;0365605
+-073;0730064;0776551
+-054;0667362;0431776
+-043;0775760;0312631
+-030;0740613;0034530
+-055;0635657;0370276
+-074;0677234;0315321
+-037;0617102;0655555
+-066;0723370;0773672
+-035;0714526;0724272
+-043;0667633;0402706
+-040;0636053;0440472
+-037;0650025;0224325
+-071;0717663;0701773
+-052;0754612;0304722

src/cmd/st7.s

@@ -0,0 +1,158 @@
+"** 12-92-119.pdf page 26
+" space travel 7
+
+clistp = 017
+br0 = 040004
+br1 = 040005
+br2 = 040006
+br3 = 040007
+
+d10: 10
+d3: 3
+o246256: 0246256
+o253052: 0253052
+o246036: 0246036
+o177: 0177
+nplan: 32
+d1: 1
+d20: 20
+dm1: -1
+o141577: 0141577
+o161577: 0161577
+o164372: 0164372
+o114: 0114
+o20714: 020714
+d383: 383
+dm768: -768
+o145777: 0145777
+o165777: 0165777
+o7: 7
+o60: 060
+o55: 055
+o53: 053
+o41: 041
+o220000: 0220000
+d400: 400
+dm20: -20
+o40004: 040004
+
+fardst: 020;0200000; 0
+f2pi: 03;0311037;552421
+pid10: -01;0240662;756647
+thrs: 02;0200000;0
+f400: 011;0310000;0
+crash: -028;0200000;0
+stheta: 01;0200000;0
+ctheta: 0;0;0
+fpzero: 0;0;0
+scale: 0
+vscale: 6
+ascale: -1
+sdphi: -05;0253436;0700177
+cdphi: 000;0377743;0201725
+dhalt: 0400000
+fpone: 01;0200000;0
+
+9: .=.+t
+horizv: .=.+3
+.pbson: .=.+1
+.pbsint: .=.+1
+dspflg: .=.+1
+par: .=.+1
+absi: .=.+1
+absx: .=.+3
+"** 12-92-119.pdf page 27
+absy: .=.+3
+v: .=.+3
+vv: .=.+3
+spx: .=.+3
+spy: .=.+3
+wx: .=.+3
+wy: .=.+3
+twx: .=.+3
+twy: .=.+3
+setx: .=.+1
+sety: .=.+1
+narcs: .=.+1
+nt: .=.+1
+inflg: .=.+1
+grvflg: .=.+1
+dtmp1: .=.+3
+dtmp2: .=.+3
+delx: .=.+1
+dely: .=.+1
+tsetx: .=.+1
+tsety: .=.+1
+accflg: .=.+1
+locpar: .=.+1
+crflg: .=.+1
+rpar: .=.+3
+dpar: .=.+3
+ax: .=.+3
+ay: .=.+3
+maxa: .=.+3
+maxj: .=.+1
+dcplan: .=.+1
+fcplan: .=.+1
+cplan: .=.+1
+shipx: .=.+3
+shipy: .=.+3
+x: .=.+3
+y: .=.+3
+ox: .=.+3
+oy: .=.+3
+lanflg: .=.+1
+goflg: .=.+1
+forflg: .=.+1
+bacflg: .=.+1
+sphi: .=.+3
+cphi: .=.+3
+ftmp1: .=.+3
+ftmp2: .=.+3
+locflg: .=.+3
+
+dsetx = 0140000
+dsety = 0164000
+vecx = 0120000
+vecy = 0124000
+m = 02000
+displist:
+	075057 "scale 1 intens 3 blink on lp 0 sym 0
+	dsetx 800
+	dsety 20
+dispcl:
+	0
+	060004 "intens 0 blink off
+"** 12-92-119.pdf page 28
+	dsetx 0
+	dsety 20
+namedsp:
+	.=.+10
+	dsetx 400
+	dsety 20
+dssca:
+	.=.+3
+	040040 "scale 0
+	dsetx 127
+	dsety 250
+	vecx 768
+	dsetx 895
+	dsety 255
+	vecy 768
+	dsetx 895
+	dsety 1023
+	vecx m 768
+	dsetx 127
+	dsety 1023
+	vecy m 768
+	dsetx 127
+	dsety 255
+	vecx 768
+	dsetx 511
+	dsety 255
+	vecy 767
+	dsetx 127
+	dsety 639
+	vecx 767
+dspl:
+	0400000